Creates a Material Design multi-line text area for longer text input such as comments, descriptions, or messages.

Syntax

Result = MaterialSB::Textarea(Label.s = "", Placeholder.s = "", Flags = #Textarea_Default, Parent = #Null)

Parameters

Label.s	Optional. Label text for the textarea.
Placeholder.s	Optional. Placeholder text shown when the textarea is empty.
Flags	Optional. Combination of textarea flags for styling and state.
Parent	Optional. Parent element. If #Null, uses the current parent from the stack.

Flags

Flag	Description
#Textarea_Default	Standard textarea (default)
#Textarea_Outlined	Outlined style textarea
#Textarea_Disabled	Disabled state
#Textarea_Readonly	Read-only state

Return Value

Returns the textarea element. Use GetValue() and SetValue() to access content.

Example

Global messageTextarea

Procedure SubmitMessage()
  Protected message.s
  !v_message = v_messagetextarea.value;
  If message <> ""
    MaterialSB::Toast("Message sent!")
    MaterialSB::SetValue(messageTextarea, "")
  Else
    MaterialSB::Toast("Please enter a message", 3000, MaterialSB::#Toast_Default, "orange")
  EndIf
EndProcedure

Procedure Main(Success)
  If Success
    MaterialSB::Row(MaterialSB::#Grid_Container)
      MaterialSB::Col(12, 8, 6)
        MaterialSB::Card()
          MaterialSB::CardContent()
            MaterialSB::Append(MaterialSB::Header("Contact Us", 4))
            
            ; Name input
            MaterialSB::TextInput("Your Name")
            
            ; Email input
            MaterialSB::TextInput("Email", "", MaterialSB::#Input_Email)
            
            ; Message textarea
            messageTextarea = MaterialSB::Textarea("", "Write your message here...")
            
          MaterialSB::CloseCurrentParent()
          MaterialSB::CardAction()
            MaterialSB::Button("Send Message", @SubmitMessage())
          MaterialSB::CloseCurrentParent()
        MaterialSB::CloseCurrentParent()
      MaterialSB::CloseCurrentParent()
    MaterialSB::CloseCurrentParent()
  EndIf
EndProcedure

MaterialSB::Download(@Main())

See Also

TextInput(), GetValue(), SetValue(), InputSetCallback()